基于显存让文字和数字在屏幕上显示

assembly-02-控制显示器显示文本

学习要点

  • 显存的位置
  • 段寄存器和偏移地址配合,ds,es
  • 批量转移 movsw,movsb,rep
  • 循环loop

显示原理

黑白:1个字节控制灰度

彩色:3个字节控制红绿蓝

显存(文本模式&图像模式)

在8086处理器中,显存映射到内存空间,位于0xB8000-0xBFFFF,用来显示文本

显存里用【字符+背景色】来组成一个字符,对应2字节,例如0x0748 48代表’h’,07代表背景色

汇编代码

mov ax,0xb800  #此处不用修饰长度,因为ax是16位,0xb800也是16位,都合理
mov ds,ax   #不允许将立即数传送到ds,需要ax中转,段寄存器是0xb800
#byte修饰目的操作数长度 [0x00]是一个字节的偏移,源操作数也是一个字节长
mov byte [0x00],'a'       #偏移地址是0x00,完整地址是b800:0000=b80000
mov byte [0x01],0x04
mov byte [0x02],'s'
mov byte [0x03],0x04
mov byte [0x04],'m'
mov byte [0x05],0x04
jmp $  #跳转到开头,表示一直显示字符在显示器
times 510-($-$$) db 0  # $代表当前行地址 $$代表当前段起始地址
db 0x55,0xaa

显示文本

  1. 编译文件
  2. 写入虚拟硬盘
  3. 启动bochsdbg.exe 查看结果

命令

x /[重复次数] [格式] [单位] 地址

x /10bx 0xb8000表示查看0xb8000的位置后面10个字节的内容,并且以16进制显示

u /[重复次数] 地址

反汇编多少条指令

断点到0x7c00执行准备第一条代码

image-20260901141856155

执行到了显示器内容已经被修改

image-20260901142012216

查看字节,此时已经把0xb8000地址的内容修改成了61,字符’a’

image-20260901142412870

继续执行剩下的指令会把后面字符也修改掉

image-20260901142607030

显示数字

要显示某个数字要先分解所有数位

125 % 10 =12…5

12 % 10 =1…2

1 % 10 =0…1

根据余数分解出来1 2 5三个,再加上0x30(0的ascii是0x30),就是对于数字的ascii字符码

div

  1. 指令中的是8位寄存器或8位操作数,被除数在ax里,余数在ah,商在al
    1. div bh (bx寄存器高8位作为被除数)
    2. div byte [0x2002] (0x2002取一个字节的作为除数)
  2. 指令中的是16位寄存器或16位操作数,被除数则是32位的,低16位在ax中,高16位在dx中,余数在dx,商在ax
    1. div bx
    2. div word [0x2002]
  3. 指令中的是32位寄存器或32位操作数,被除数则是64位的,低32位在eax中,高16位在edx中,余数在edx,商在eax
    1. div ebx
    2. div dword [0x2002]
  4. 指令中的是64位寄存器或64位操作数,被除数则是128位的,低32位在rax中,高32位在rdx中,余数在rdx,商在rax
    1. div rbx
    2. div qword [0x2002]

举例

start:
	mov ax,65535
	mov dx,0
	mov bx,10
	div bx
current:
	times 510-(current - start) db 0
	db 0x55,0xaa

rax高16位和rdx低16位作为被除数 65535,rbx 设置为除数10

image-20260901204809304

65535 /10 = 6553 … 5,商保存在rax中,余数保存在rdx中

image-20260901205037247

在屏幕显示65535

学习es段寄存器作用,内存地址存放数据,除法

start:

	;设置数据段寄存器
	mov cx,0x7c0
	mov ds, cx 

	;65535/10
	mov ax,65535
	mov dx,0
	mov bx,10
	div bx
	;余数数字转化成字符
	add dl,0x30
	;把余数字符保存在buffer里
	mov byte [0x00 + buffer],dl
	
	;一直重复设置商到buffer处
	mov dx,0
	div bx
	add dl,0x30
	mov byte [0x01 + buffer],dl
	
	mov dx,0
	div bx
	add dl,0x30
	mov byte [0x02 + buffer],dl
	
	mov dx,0
	div bx
	add dl,0x30
	mov byte [0x03 + buffer],dl
	
	mov dx,0
	div bx
	add dl,0x30
	mov byte [0x04 + buffer],dl
	
	;使用es作为显存的段寄存器
	mov cx,0xb800
	mov es,cx
	
	
	;buffer的尾地址的字符保存在al中,此时的段寄存器位ds=0x7c0
	mov al, [0x04 + buffer]
	mov [es:0x00],al
	mov byte [es:0x01],0x2f
	
	
	mov al, [0x03 + buffer]
	mov [es:0x02],al
	mov byte [es:0x03],0x2f
	
	mov al, [0x02 + buffer]
	mov [es:0x04],al
	mov byte [es:0x05],0x2f
	
	mov al, [0x01 + buffer]
	mov [es:0x06],al
	mov byte [es:0x07],0x2f
	
	mov al, [0x00 + buffer]
	mov [es:0x08],al
	mov byte [es:0x09],0x2f
	
again:
	jmp again
	
	
buffer:
	db 0,0,0,0,0	
	
current:
	times 510-(current - start) db 0
	db 0x55,0xaa

优化在屏幕显示65535

movsb: 按byte串传送

movsw: 按word串传送

要使用传送需要准备4个寄存器的地址

ds,si 原始数据串的段地址,偏移地址

es,di 目标位置的段地址,偏移地址

定义一个缓存区,从缓冲区区字符放入显存

只有bx si di bp可以存偏移地址

		jmp start
mytext db 'H',0x07,'E',0x07,'L',0x07,'L',0x07,'O',0x07
	   db 'W',0x07,'O',0x07,'R',0x07,'L',0x07,'D',0x07
start:
;需求1,把mytext缓存的值显示在显示器
	mov ax,0x7c0 ;数据段的开始地址是0x7c00
	mov ds,ax
	
	mov ax,0xb800   ;显存的开始地址是0xb8000
	mov es,ax
	
	
	cld ;flags寄存器,方向标志df清0,表示从低->高传送,从mytext开始每次+2word(如果反过来,则使用std,应该从start前一位开始,每次-2word)
	mov si,mytext
	mov di,0
	mov cx,(start - mytext)/2
	rep movsw     ;rep代表反复执行传送指令 cx指定次数
	
	
;需求2 显示number处的汇编地址,显示在显示器
	mov ax, number
	;使用除法分解数字
	mov bx,ax
	mov cx,5   ;cx作为循环次数
	mov si,10
	
digit:
	mov dx,0
	div si
	mov [bx],dl   ;访问内存bx里number的偏移地址,注意:只有bx si di bp可以存偏移地址
	inc bx
	loop digit

	mov si,4
	mov bx,number
	mov di,(start - mytext)
	mov cx,5
show:
	mov al,[bx+si]
	add al,0x30
	mov byte [es:di],al
	inc di
	mov byte [es:di],0x07
	inc di
	dec si
	loop show
	
	jmp $

number:
	db 0,0,0,0,0
	
	times 510 - ($-$$) db 0 ;$当前地址 $$段起始汇编地址
	db 0x55,0xaa