基于例子 “1+2+3+….+99=4950” 来学习栈的使用

1. 问题与目标

背景: 计算出结果取出数位,先取的是最低位,但是显示在屏幕上先显示的是最高位,这样每次取数和显示都是相反的顺序,不方便

目标:学会使用栈来存取数据

2. 前置知识与环境

需要先了解:汇编的循环,显存显示,内存取数存数据;

项目 本文使用的值
操作系统 / 架构 x86_64
工具 / 依赖 NASM编译器

3. 核心概念与整体流程

先用自己的话说明核心机制,再进入代码或操作细节。16位8086栈操作必须是一个word(16位)

概念 含义
push SP=SP-数字节大小,写入
pop 取出SP处数据,SP=SP+数字节大小
SP寄存器 栈段地址
SS寄存器 栈段偏移地址,栈的顶部

关键原因:【解释为什么采用这一流程,以及成立的条件。】

4. 实现过程

4.1 无栈的计算

目的:没有栈是如何操作

jmp start

message:
	db '1+2+3+...+99='

start:
    ;寄存器初始化
	;代码段
	mov bx, 0x7c0
	mov ds, bx
	
	;显存段
	mov bx, 0xb800
	mov es, bx
	
	
	
	; 1. 打印字符串 
	mov cx, start - message ;cx保存字符串长度,做为循环打印的次数
	mov si, 0               ; si 保存写入的显存偏移地址
	mov bx, message         ;bx存放message开始地址,从这里开始取数
print_message:
	mov al, [bx]
	mov ah, 0x07
	mov [es:si], ax
	add si, 2				 ;下一个显存写入地址
	inc bx                   ;移动到下一个字符
	loop print_message

	; 2. 计算和 (ax = 4950)
	mov ax, 0
	mov bx, 1
	mov cx, 99
sum:	
	add ax, bx
	inc bx
	loop sum

	; 3. 把 ax 拆分存入 result_addr (得到的顺序是 0,5,9,4)
	mov di, result_addr     ; di 指向缓冲区
	mov bx, 10
	mov cx, 0               ; cx 用来记录一共拆出了几位数字

show_result:
	mov dx, 0               ; 除法前 DX 清零
	div bx                  ; ax = 商, dx = 余数
	
	add dl, 0x30            ; 余数转 ASCII
	mov [di], dl            ; 存入缓冲区
	inc di                  ; 缓冲区指针后移
	inc cx                  ; 字符位数 +1
	
	cmp ax, 0
	jne show_result         ; 商不为 0 则继续拆分

	; 4. 倒序读取 result_addr 并写入显存
	; 此时 di 指向最后一个字符的下一个位置,di - 1 即为最后一个字符
	dec di

print_result:
	mov al, [di]            ; 倒序读取字符(先读最高位 '5')
	mov ah, 0x07            ; 属性:黑底白字
	mov [es:si], ax         ; 写入显存
	add si, 2               ; 【修正】显存递增 2 字节
	dec di                  ; 指针前移,取上一位
	loop print_result       ; 循环 cx 次

	jmp $                   ; 【修正】在这里卡死,防止 CPU 执行后面的数据

result_addr:	
	db 0,0,0,0,0

times 510-($-$$) db 0
db 0x55,0xaa

4.2 有栈的优化

内存布局

ss和sp都设置为0,目的是可以防止和ds冲突

如果PUSH会让指针回到最顶部,让栈向下增长

image-20260901141856155

目的:使用栈来存放结果,方便存和取

jmp start

message:
	db '1+2+3+...+99='

start:
    ;寄存器初始化
	;代码段
	mov bx, 0x7c0
	mov ds, bx
	
	;显存段
	mov bx, 0xb800
	mov es, bx
	
	
	
	; 1. 打印字符串 
	mov cx, start - message ;cx保存字符串长度,做为循环打印的次数
	mov si, 0               ; si 保存写入的显存偏移地址
	mov bx, message         ;bx存放message开始地址,从这里开始取数
print_message:
	mov al, [bx]
	mov ah, 0x07
	mov [es:si], ax
	add si, 2				 ;下一个显存写入地址
	inc bx                   ;移动到下一个字符
	loop print_message

	; 2. 计算和 (ax = 4950)
	mov ax, 0
	mov bx, 1
	mov cx, 99
sum:	
	add ax, bx
	inc bx
	loop sum

	; 3. 把 ax 拆分存入 栈 (得到的顺序是 0,5,9,4)
	mov cx, 0
	
	;设置栈的地址
	mov sp, cx
	mov ss, cx
	mov bx, 10
	mov cx, 0               ; cx 用来记录一共拆出了几位数字

show_result:
	mov dx, 0               ; 除法前 DX 清零
	div bx                  ; ax = 商, dx = 余数
	
	add dl, 0x30            ; 余数转 ASCII
	push dx					;16位8086栈操作必须是一个word(16位)
	inc cx                  ; 字符位数 +1
	
	cmp ax, 0
	jne show_result         ; 商不为 0 则继续拆分

	; 4. 倒序读取 result_addr 并写入显存
	; 此时 di 指向最后一个字符的下一个位置,di - 1 即为最后一个字符
print_result:
	pop ax
	mov ah, 0x07            ; 属性:黑底白字
	mov [es:si], ax         ; 写入显存
	add si, 2               ; 【修正】显存递增 2 字节
	loop print_result       ; 循环 cx 次

	jmp $                   ; 【修正】在这里卡死,防止 CPU 执行后面的数据


times 510-($-$$) db 0
db 0x55,0xaa

5. 结果验证

最终结果 4950,存入栈,从0xfffe开始到0xfff8,push4次,总共4个word

查看地址0xfff8往后的字符表示

image-20260901141856155

也可以直接打印命令查看栈,均符合预期

image-20260901141856155

push dx之前 sp寄存器为0

image-20260901141856155

最终显示

image-20260901141856155