Intel8086的寻址方式

1. 问题与目标

背景:了解8086寻址方式

目标:寄存器寻址,立即数寻址,直接内存寻址

2. 前置知识与环境

去哪里找到要操作的数据

3. 核心概念与整体流程

3.1 寄存器寻址

;目的操作数和源操作数是寄存器
mov ax,cx
;目的操作数寄存器
inc dx

3.2 立即数寻址

;源操作数立即数寻址
add bx,0xf000
;源操作数立即数寻址
mov dx,mydata

3.3 直接内存寻址

mov ax,[0x5c0f]
add word [0x2030],0x5000
xor byte [es:di],0x05

3.3.1 基址寻址

基址寄存器,bx(默认段是ds)或者bp(默认段是ss),例如处理数组类型的数据,定位起始地址

案例1:bx

;bx存放buffer的偏移地址
mov bx,buffer
;循环5次
mov cx,5
loop_code:
	;buffer指针的数据取出来+1
	inc word [bx]
	;buffer指针向后移动
	add bx,2
	loop loop_code

案例2:bx

mov bx,sp
mov dx,[ss:bx+2] ;从栈中取出0x5到dx

3.3.3 变址寻址

变址寄存器,di或者si(默认段是ds)来提供偏移地址,例如处理数组类型的数据,用来定位从开始地址走到第几个

3.3.4 基址变址寻址

基址寄存器和变址寄存器,组合使用,通过基址寄存器获得起始地址,通过变址寄存器获得数组偏移,让程序书写更方便,更直观

mov [bx+si],al

3.3.5 总结

基址寻址解决“从哪里开始”,变址寻址解决“走到第几个”。

BX
├─ 普通寻址默认 DS
├─ 属于“基址”角色
└─ 可以和 SI / DI 组合

SI
├─ 普通寻址默认 DS
├─ 属于“变址”角色
├─ 可以和 BX / BP 组合
└─ 字符串指令中隐含作为 DS:SI 源地址

DI
├─ 普通寻址默认 DS
├─ 属于“变址”角色
├─ 可以和 BX / BP 组合
└─ 字符串指令中隐含作为 ES:DI 目的地址

4. 实现反转字符串

4.1 使用基址寄存 bx 器实现

使用栈实现反转

jmp start

message:
	db 'hello world'

start:
    ;寄存器初始化
	;代码段
	mov bx, 0x7c0
	mov ds, bx
	
	;显存段
	mov bx, 0xb800
	mov es, bx
	
	;栈初始化
	mov bx,0
	mov sp,bx
	mov ss,bx


	mov cx,start - message
	mov bx,message ;数组起始地址移动到 基址寄存器bx
push_msg:
	mov ax,0
	mov al,[bx] ;不能直接从bx所在位置取数据,因为不知道取多少个,所以使用al,来每次取8位一个字符
	push ax    ;虽然一个字符8位,但是栈一个单位是16位
	inc bx
	loop push_msg


	mov cx,start - message	
	mov bx,0
pop_msg:
	pop ax
	mov ah,0x07    ;低8位是字符,高8位是颜色,组成ax

	mov [es:bx],ax
	add bx,2
	loop pop_msg

jmp $

times 510-($-$$) db 0
db 0x55,0xaa

4.2 使用基址(bx)+变址寄存器(si)实现

双指针让字符前后交换,实现反转

jmp start

message:
	db 'hello world'

start:
    ;寄存器初始化
	;代码段
	mov bx, 0x7c0
	mov ds, bx
	
	;显存段
	mov bx, 0xb800
	mov es, bx
	
	
	;数组开始地址
	mov bx,message
	;数组头指针
	mov si,0
	;数组尾指针
	mov di,start-message-1
	
reverse:
	mov ax, 0
	mov al,[bx+si]
	mov ah,[bx+di]
	mov [bx+si],ah
	mov [bx+di],al
	inc si
	dec di
	cmp si,di
	jl reverse
	
	
	mov cx,start-message
	mov bx,message
	mov di,0
print_msg:
	mov ax, 0
	mov al,[bx]
	mov ah,0x7
	mov word [es:di],ax
	add di,2
	inc bx
	loop print_msg
	
jmp $

times 510-($-$$) db 0
db 0x55,0xaa	

5. 结果验证

image-20260901141856155