硬盘的访问

1. 目标

目标:

  • 模拟从硬盘加载应用程序,演示段重定位,理解内存内存管理机制
  • X86访问外围设备的方法
  • 实现读取用户程序执行代码

2. 前置知识与环境

  • 代码段
  • 数据段
  • 栈段

3. 核心概念与整体流程

3.1 对齐

vstart:计算的符号地址

align:对齐长度

section s1
offset dw str1,str2,num

section s2 align=16 vstart=0x100
str1 db 'hello'
str2 db 'world'

section s3 align=16
num dw 0xbad

offset的值是 0x0100 0x0105 0x0020


0x00 ┌───────────────┐
     │ s1            │
     │ 6 bytes       │
0x06 ├───────────────┤
     │ padding       │
     │ 10 bytes      │
0x10 ├───────────────┤
     │ s2            │ ← 文件偏移 0x0010
     │ str1 "hello"  │ ← 虚拟地址 0x0100
     │ str2 "world"  │ ← 虚拟地址 0x0105
     │ 共 10 bytes   │
0x1A ├───────────────┤
     │ padding       │
0x20 ├───────────────┤
     │ s3            │
     │ num           │ ← 地址 0x0020
     └───────────────┘

3.2 用户程序头部

  • 程序总长度
  • 入口点
  • 段重定位表项数
  • 段重定位表

头部示例

SECTION header vstart=0                     ;定义用户程序头部段 
    program_length  dd program_end          ;程序总长度[0x00]
    
    ;用户程序入口点
    code_entry      dw start                ;偏移地址[0x04]
                    dd section.code_1.start ;段地址[0x06] 
    
    realloc_tbl_len dw (header_end-code_1_segment)/4
                                            ;段重定位表项个数[0x0a]
    
    ;段重定位表           
    code_1_segment  dd section.code_1.start ;[0x0c]
    code_2_segment  dd section.code_2.start ;[0x10]
    data_1_segment  dd section.data_1.start ;[0x14]
    data_2_segment  dd section.data_2.start ;[0x18]
    stack_segment   dd section.stack.start  ;[0x1c]
    
    header_end:   

3.3 加载器

  • 读取起始扇区
  • 读取到内存(0x10000-9FFFF)
  • 计算物理地址和逻辑地址(重定位)
  • 转移到用户程序执行

加载器示例

         ;文件说明:硬盘主引导扇区代码(加载程序)
         app_lba_start equ 100           ;声明常数(用户程序起始逻辑扇区号)
                                         ;常数的声明不会占用汇编地址
                                    
SECTION mbr align=16 vstart=0x7c00                                     

         ;设置堆栈段和栈指针 
         mov ax,0      
         mov ss,ax
         mov sp,ax
      
         mov ax,[cs:phy_base]            ;计算用于加载用户程序的逻辑段地址 
         mov dx,[cs:phy_base+0x02]
         mov bx,16        
         div bx            
         mov ds,ax                       ;令DS和ES指向该段以进行操作
         mov es,ax                        
    
         ;以下读取程序的起始部分 
         xor di,di
         mov si,app_lba_start            ;程序在硬盘上的起始逻辑扇区号 
         xor bx,bx                       ;加载到DS:0x0000处 
         call read_hard_disk_0
      
         ;以下判断整个程序有多大
         mov dx,[2]                      ;曾经把dx写成了ds,花了二十分钟排错 
         mov ax,[0]
         mov bx,512                      ;512字节每扇区
         div bx
         cmp dx,0
         jnz @1                          ;未除尽,因此结果比实际扇区数少1 
         dec ax                          ;已经读了一个扇区,扇区总数减1 
   @1:
         cmp ax,0                        ;考虑实际长度小于等于512个字节的情况 
         jz direct
         
         ;读取剩余的扇区
         push ds                         ;以下要用到并改变DS寄存器 

         mov cx,ax                       ;循环次数(剩余扇区数)
   @2:
         mov ax,ds
         add ax,0x20                     ;得到下一个以512字节为边界的段地址
         mov ds,ax  
                              
         xor bx,bx                       ;每次读时,偏移地址始终为0x0000 
         inc si                          ;下一个逻辑扇区 
         call read_hard_disk_0
         loop @2                         ;循环读,直到读完整个功能程序 

         pop ds                          ;恢复数据段基址到用户程序头部段 
      
         ;计算入口点代码段基址 
   direct:
         mov dx,[0x08]
         mov ax,[0x06]
         call calc_segment_base
         mov [0x06],ax                   ;回填修正后的入口点代码段基址 
      
         ;开始处理段重定位表
         mov cx,[0x0a]                   ;需要重定位的项目数量
         mov bx,0x0c                     ;重定位表首地址
          
 realloc:
         mov dx,[bx+0x02]                ;32位地址的高16位 
         mov ax,[bx]
         call calc_segment_base
         mov [bx],ax                     ;回填段的基址
         add bx,4                        ;下一个重定位项(每项占4个字节) 
         loop realloc 
      
         jmp far [0x04]                  ;转移到用户程序  
 
;-------------------------------------------------------------------------------
read_hard_disk_0:                        ;从硬盘读取一个逻辑扇区
                                         ;输入:DI:SI=起始逻辑扇区号
                                         ;      DS:BX=目标缓冲区地址
         push ax
         push bx
         push cx
         push dx
      
         mov dx,0x1f2
         mov al,1
         out dx,al                       ;读取的扇区数

         inc dx                          ;0x1f3
         mov ax,si
         out dx,al                       ;LBA地址7~0

         inc dx                          ;0x1f4
         mov al,ah
         out dx,al                       ;LBA地址15~8

         inc dx                          ;0x1f5
         mov ax,di
         out dx,al                       ;LBA地址23~16

         inc dx                          ;0x1f6
         mov al,0xe0                     ;LBA28模式,主盘
         or al,ah                        ;LBA地址27~24
         out dx,al

         inc dx                          ;0x1f7
         mov al,0x20                     ;读命令
         out dx,al

  .waits:
         in al,dx
         and al,0x88
         cmp al,0x08
         jnz .waits                      ;不忙,且硬盘已准备好数据传输 

         mov cx,256                      ;总共要读取的字数
         mov dx,0x1f0
  .readw:
         in ax,dx
         mov [bx],ax
         add bx,2
         loop .readw

         pop dx
         pop cx
         pop bx
         pop ax
      
         ret

;-------------------------------------------------------------------------------
calc_segment_base:                       ;计算16位段地址
                                         ;输入:DX:AX=32位物理地址
                                         ;返回:AX=16位段基地址 
         push dx                          
         
         add ax,[cs:phy_base]
         adc dx,[cs:phy_base+0x02]
         shr ax,4
         ror dx,4
         and dx,0xf000
         or ax,dx
         
         pop dx
         
         ret

;-------------------------------------------------------------------------------
         phy_base dd 0x10000             ;用户程序被加载的物理起始地址
         
 times 510-($-$$) db 0
                  db 0x55,0xaa

3.4 输入输出端口

目的寄存器必须 dx

源必须用 ax

从端口读数据到ax

in al,0x60

从ax发送数据端口

out 0x67.ax

硬盘是以 块 为单位读取和写入数据

**CHS **模式:Cylinder Header Sector

**LBA **模式:逻辑扇区模式

**LBA **模式

1.写入端口
out dx,ax

1. 设置起始LBA扇区号(28位),分别写入端口
  1. 0x1f3 (7 - 0)
  2. 0x1f4 (15 - 8)
  3. 0x1f5 (23 - 16)
  4. 0x1f6 硬盘模式(4位)+(逻辑扇区27-24)
    1. 第7位:默认1
    2. 第5位:默认1
    3. 第6位 :0代表CHS,1代表LBA
    4. 第4位:0主硬盘,1从硬盘
    5. 第3-0位:逻辑扇区的(27-24)位

image-20260901141856155

;实例
;扇区号0000 00000000 00000000 00000010
;(7 - 0) 00000010
mov dx,0x1f3
mov al,0x02
out dx,al

;(15 - 8) 00000000
inc dx
mov al,0x00
out dx,al

; (23 - 16) 00000000
inc dx
mov al,0x00
out dx,al

;主硬盘模式以及LBA 27-24 11100000
inc dx
mov al,0xe0
out dx,al


2. 请求硬盘读

向 端口 0x1f7 写入0x20,表示开始读

mov dx,0x1f7
mov al,0x20
out dx,al
3 等待读写

image-20260901141856155

从端口0x1f7读取,7位是0,和3位是1,才可以读取

mov dx,0x1f7
;7位是0,和3位是1,才可以读取
.waits:
	in al,dx
	and al,0x88
	cmp al,0x08
	jnz .waits
4. 连续取出数据

DS指向存放扇区的数据段,BX是段内偏移地址

mov cx,256 ;读取次数
mov dx,0x1f0
.readw:
	in ax,dx ;每次读2个字节
	mov [bx],ax
	add bx,2
	loop .readw

5. 结果验证

.